各统计指标之间常呈现相关，这也是人们很想知道的事情。存在相关的两个指标之间，其相关系数有多大？如何计算？本节拟介绍 4 种相关系数及其计算方法。
等级（秩次）资料的直线相关分析叫等级相关。 本节介绍Spearman等级相关系数与 Kendall等级相关系数两种。
Ⅰ．Spearman等级相关分析
1. Spearman等级相关的概念
Spearman 等级相关，又叫“秩相关”、“顺序相关检验”，是一种较简易、不十分精确的指标之间相互关系的测定方法，是一种非参数分析方法。等级相关是分析两个指标的等级（秩次）之间是否相关的一种方法。等级型 / 半定量的数据，不宜用线性相关回归分析法，须用等级相关系数计算法。设等级相关系数为 rs:
6 ∑d2
rs = 1 - -------------------
n (n2-1)
上式如 SPSS 语法写可表示为：
rs = 1 - 6 * sd2/(n*(n**2-1))
式中 rs 为等级相关系数，d 为两个等级的差值，n 为样本含量（式中按 SPSS 语法的算式写，“sd2” 为 d2 的总和值，即∑d2 , “*”表示“乘以”；“**”表示“乘方”）。当 n≤15 时，须查专用的工具表判定显著性；当 n＞15 时按线性相关显著性界限处理。
例如：请对某省地方性甲状腺肿患病率（morb）与当地食品与水中含碘量的关系数据，计算其等级相关系数，说明两者间的关系。
表 6-1 某地地方性甲状腺肿患病率（%）与其食品、水中含碘量的数据
------------------------------------------------------------------------------------------
等级（秩次)
---------------------- 等级差
调查地点 含碘量（I） 患病率（morb） 含碘量 患病率 d d2
------------------------------------------------------------------------------------------
1 201 0.2 1 7 -6 36
2 178 0.6 2 6 -4 16
3 155 1.1 3 4 -1 1
4 154 0.8 4 5 -1 1
5 126 2.5 5 3 2 4
6 81 4.4 6 2 4 16
7 71 16.9 7 1 6 36
-----------------------------------------------------------------------------------------
合计 - - - - - 110
-----------------------------------------------------------------------------------------
2. Spearman等级相关计算程序
所用程序文件名为 CorreRegre2.sps 的例 *1。
-------------------------------------------------------------------
*1. Pan Bao-Jun: Application of Calculator in Med. Stat.,P.120:.
*Spearman correlation:.
DATA LIST FREE / Place I morb.
BEGIN DATA.
1 201 0.2
2 178 0.6
3 155 1.1
4 154 0.8
5 126 2.5
6 81 4.4
7 71 16.9
END DATA.
COMPUTE n=7.
RANK VARIABLES=I morb /RANK INTO IR morbR.
COMPUTE d=IR-morbR.
COMPUTE d2=d**2.
FORMATS Place I IR morbR d d2(F5.0) morb(F5.1).
LIST VARIABLES=Place I morb IR morbR d d2 /FORMAT=NUMBERED /CASES=FROM 1 TO 7.

CREATE sd2=CSUM(d2).
COMPUTE rs=1-6*sd2/(n*(n**2-1)).
FORMATS rs(F12.9).
LIST VARIABLES rs /CASES=FROM 7 TO 7.
NONPAR CORR /VARIABLES=I morb /PRINT=SPEARMAN TWOTAIL NOSIG.
NONPAR CORR /VARIABLES=I morb /PRINT=KENDALL TWOTAIL NOSIG.
*--------------------------------------------------------------------------.
注意：程序中其实只要用倒数第二句“NONPAR CORR /VARIABLES=I morb /PRINT=SPEARMAN TWOTAIL NOSIG. ”命令（意为非参数相关）足矣。
3. Spearman等级相关系数的计算结果
计算结果等级相关系数 rs为 -0.964285714（前面用了好几句命令的算法，只是让大家知道按公式计算的过程；与倒数第二句“NONPAR CORR /VARIABLES=I morb /PRINT = SPEARMAN TWOTAIL NOSIG.”命令算出的结果完全相同）,此值大于“等级相关系数 rs 界值表”（表 6-2）中的 r0.01 = 0.929, 故 P＜0.01，说明甲状腺肿患病率与当地食品水中含碘量之间呈负相关，即含碘量越高，患病率就越低。
---------------------------------------------------------------
RS
-0.964285714
Number of cases read: 7 Number of cases listed: 1
---------------------------------------------------------------
Correlations
I MORB
Spearman's rho I Correlation Coefficient 1.000 -0.964
Sig. (2-tailed) . .000
N 7 7
MORB Correlation Coefficient -0.964 1.000
Sig. (2-tailed) .000 .
N 7 7
** Correlation is significant at the .01 level (2-tailed).

表 6-2 等级相关系数 rs 界值表
------------------------------------------------------------
n P(2): 0.01 0.05 0.02 0.01
-----------------------------------------------------------
4 1.000
5 0.900 1.000 1.000
6 0.829 0.886 0.943 1.000
7 0.714 0.786 0.893 0.929
8 0.643 0.738, 0.833 0.881
9 0.600 0.700 0.783 0.833
10 0.564 0.648 0.745 0.794
11 0.563 0.618 0.709 0.755
12 0.503 0.587 0.678 0.727
13 0.484 0.560 0.648 0.703
14 0.464 0.538 0.626 0.679
15 0.446 0.521 0.604 0.654
16 0.429 0.503 0.582 0.635
17 0.414 0.485 0.566 0.615
18 0.401 0.472 0.550 0.600
19 0.391 0.460 0.535 0.584
20 0.380 0.447 0.520 0.570
-----------------------------------------------------------
“NONPAR CORR” 一句的计算结果(Spearman rs=-0.964)，与用等级相关系数计算公式（rs）的计算结果是相同的：1 - (6 × 110)/(7(72 -1)) = -0.964。