Spss电脑实验－第七节(2)动态数列及其外延预测法

spss_SAS

Ⅱ．动态数列及其外延预测法
1. 动态数列简介
动态数列的分析，在 SPSS 语句中可用一个很简单、有效的公式来计算：（** 表示乘方）
an = a0 * ( 1 + r )** n
此公式即“复利计算公式”：F = P *(1 +i )** n
式中 a0 或 P为现在值（present）；an 或 F 为将来值（future）；r 或 i 为“增长率”或“复利率”；n 为经过的年数。注意：当年为“0”年！例如，从 1995 至 2003 年共 “9” 年，相当于 n 从 “0”至 “8”。
例如用这个公式来预测我国的人口数。1949 年 至 2002 年的人口数见数据库文件 CHN-FJ-Info.sav。所用程序文件名为 CHN-FJ-Info2.sps。
2. 55 年来的我国人口数增长趋势拟合
2.1 预测 2003 年中国人口数：见程序中的 (1)。这部分是以 11 种曲线来拟合（用具体年份“year”来拟合。即前述第二种方法）。结果拟合较好的曲线模型为直线方程（LIN）与对数曲线方程（LOG）。2003 年（从 1949 年算起，n=55）中国人口数的预测值：
直线方程预测为：FIT_1=132401（万人）；对数曲线方程预测为：FIT_2=132206（万人）。

------------------------------------------------------------------------------------------------------------------------
Independent: year
Upper
Dependent Mth Rsq d.f. F Sigf bound b0 b1 b2 b3
------------------------------------------------------------------------------------------------------------------------
CHNPOP LIN .995 52 11133.6 .000 -3.E+06 1494.62
CHNPOP LOG .995 52 10924.0 .000 -2.E+07 2952361
CHNPOP INV .995 52 10664.4 .000 3043399 -6.E+09
9 CHNPOP QUA .995 52 11286.6 .000 -1.E+06 .3783
9 CHNPOP CUB .995 52 11378.2 .000 -893079 .0001
CHNPOP COM .986 52 3616.86 .000 2.3E-10 1.0171
CHNPOP POW .986 52 3798.60 .000 2.0-106 33.5747
CHNPOP S .987 52 3991.33 .000 44.9719 -66342
CHNPOP GRO .986 52 3616.86 .000 -22.177 .0170
CHNPOP EXP .986 52 3616.86 .000 2.3E-10 .0170
CHNPOP LGS .986 52 3616.86 .000 . 4.3E+09 .9832
------------------------------------------------------------------------------------------------------------------------
Notes: 9 Tolerance limits reached; some dependent variables were not entered.

直线方程预测2003 年中国人口数 对数曲线方程预测2003 年中国人口数
从所绘曲线可见，1961年“困难时期”有一个人口数下降的 “凹”。
*Predicting, Graphing etc; Filename: CHN-FJ-Info2.sps.
*----------------------------------------------------------------------------.
*(1) The Population Trend of China and predicting:.
GET FILE='c:spsssavCHN-FJ-Info.sav'.
DESCRIPTIVES VARIABLES=ALL /STATISTICS=DEFAULT.
* For CHN population curve estimation.
GRAPH /LINE(SIMPLE)=VALUE(CHNpop) BY year.
CURVEFIT /VARIABLES=CHNpop WITH year
/CONSTANT
/MODEL=ALL
/PLOT=FIT
/SAVE=PRED RESID.
*FIT_1: Linear curve (LIN):.
GRAPH /LINE(MULTIPLE)=VALUE(CHNpop, FIT_1) BY year.
*FIT_2: Logarithmic curve (LOG):.
GRAPH /LINE(MULTIPLE)=VALUE(CHNpop, FIT_2) BY year.

FORMATS FIT_1 FIT_2(F9.0).
LIST VARIABLES=year CHNpop FIT_1 FIT_2
/FORMAT=NUMBERED /CASES=FROM 1 TO 55.
*----------------------------------------------------------------------------.
*(2) Estimating increasing rate "r":.
*For Time Serious, "n" must begin at "0":.
*Between 1949 and 2003: n=54:.
COMPUTE n=54.
COMPUTE an=132401.
COMPUTE a0=54167.
COMPUTE r=((an/a0)**(1/n)-1).
VARIABLE LABELS r '%, Increasing rate'.
FORMAT r(F6.4).
LIST VARIABLES=r /CASES=FROM 1 TO 1.
*So getting r=0.0167.
*----------------------------------------------------------------------------.
*(3) Estimating future value "an":.
*Between 1949 and 2003: n=54:.
COMPUTE n=54.
COMPUTE a0=54167.
COMPUTE r=0.0167.
COMPUTE an=a0*(r+1)**n.
FORMATS an(F12.0).
LIST VARIABLES=an /CASES=FROM 1 TO 1.

*Between 1949 and 2010: n=61:.
*If estimated rate of population natural increasing=0.015:.
COMPUTE n=61.
COMPUTE a0=54167.
COMPUTE r=0.015.
COMPUTE an=a0*(r+1)**n.
LIST VARIABLES=an /CASES=FROM 1 TO 1.
*-----------------------------------------------------------------------------.
*(4) Estimating No. of years, "n" :.
*If population reaches to 150000:.
COMPUTE an=150000.
COMPUTE r=0.015.
COMPUTE a0=54167.
COMPUTE n=LG10(an/a0)/LG10(1+r).
FORMATS n(F6.0).
LIST VARIABLES=n /CASES=FROM 1 TO 1.
*So getting n=68, means Year=2015.
*-----------------------------------------------------------------------------.
2.2 预测人口“增长率”r：见程序中的 (2)。这部分是以动态数列公式来预测人口“增长率”r。已知 1949 年期初人口数为 54167万人（a0），2003 年为132401万人。这 54 年来（n = 54) 的人口“增长率”r 是多少？
结果这 54 年来的人口“增长率”r = r=((an/a0)**(1/n)-1) =0.0167 = 16.7‰。
2.3 预测期末人口数 an （预测 2003 年与 2010 年人口数）：见程序中的 (3)。这部分一是已知1949 年期初人口数为 54167万人（a0），到 2003 年为54 年（n=54），若人口“增长率”r=0.0167，预测 2003 年人口数（an）是多少？结果 an = a0*(r+1)**n = 132479万人。
二是已知1949 年期初人口数为 54167万人（a0），到 2010 年为61 年（n = 61），若人口“增长率”r = 0.015，预测 2010 年人口数（an）是多少？
结果 2010 年的人口数 an=a0*(r+1)**n = 134327万人。
2.4 预测中国人口数达 15 亿的年份：见程序中的 (4)。这部分已知1949 年期初人口数为 54167万人（a0），期末人口数 an = 150000万人，若人口“增长率”r = 0.015，那么中国人口达 15 亿时的年份可从求得的 n 来推知：
n = LG10(an/a0)/LG10(1+r) = 68，即 2015 年。
注意：要准确预测我国的人口数增长趋势，实在会牵涉到许许多多因素，有许多百家争鸣、有许多不同方法、有许多不同的影响因素，各种预测结果也很不相同。使用上述方法、上述程序文件来预测我国的人口数，难免过于简单化了，因为这里仅以人口“增长率”与经过的“年数”两个自变量（影响因素）来预测。使用此程序文件，仅是作为课堂练习、学习而已。
中国人口信息研究所的预测结果是：
表 7-1 2003—2050 年中国的预期人口数（亿）
--------------------------------------------------------------------
年份 预期人口（亿） 年份 预期人口（亿）
--------------------------------------------------------------------
2003 13.01 2015 14.30
2004 13.12 2020 14.72
2005 13.22 2025 15.04
2006 13.32 2030 15.25
2007 13.43 2035 15.38
2008 13.54 2040 15.44
2009 13.65 2045 15.38
2010 13.77 2050 15.22
--------------------------------------------------------------------

图 7-1 2003—2050 年中国的预期人口数（亿）（中国人口信息研究所预测